Asphyre4.0+Delphi2007
程序组织结构分析
逆水寒
本文根据火人的MouseEvent范例分析而来，主要说明一下Asphyre4.0的资源组织形式和程序结构。我将把这个范例一起上传，也可以到上面的网址中去下载。这个范例中使用Asphyre4.0以及Sprite Engine.
下载了Asphyre4.0和Sprite Engine for Asphyre4文件后，在Delphi2007的Library环境变量中包含其目录即可.不要去安装控件.
新建一个VCL Win32应用程序.
添加引用单元
Interface部分：
uses
AsphyreDevices, AsphyreTimer, AsphyreTypes, AsphyreImages,
AsphyrePalettes, AsphyreEffects, AsphyreSprite, AsphyreSpriteEffects,
AsphyreSpriteUtils,AsphyreSystemFonts,AsphyreEvents;
Implementation部分：
uses
AsphyreArchives, MediaImages, CommonUtils, MediaFonts;
初始化设备
在FormCreate事件中解析图片及字体资源XML文件。
ImageGroups.ParseLink('/media.xml');
FontGroups.ParseLink('/media.xml');
Devices.Count:= 1;
if (not Devices.Initialize(DevConfig, Self)) then
begin
ShowMessage('Initialization failed.');
Close();
Exit;
end;
Timer.Enabled:= True;
Timer.OnTimer:= TimerEvent;
Timer.MaxFPS:= 4000;
这里有两个过程需要创建：DevConfig及TimerEvent.
1 对显示设备初始化的DevConfig过程
procedure TMainForm.DevConfig(Sender: TAsphyreDevice; Tag: TObject;
var config: TScreenConfig);
begin
Config.Width := 800;
Config.Height := 600;
Config.Windowed:= true;
Config.VSync := true;
Config.BitDepth:= bd24Bit;
Config.WindowHandle:= Self.Handle;
Config.HardwareTL := False;
Config.DepthStencil:= dsNone;
EventDeviceCreate.Subscribe(PreloadEvent, Sender);
end;
这里要在PreloadEvent过程中创建精灵引擎以及精灵。
procedure TMainForm.PreloadEvent(Sender: TObject; EventParam: Pointer; var Success: Boolean);
var
i: Integer;
begin
if (Sender is TAsphyreDevice) then
with Sender as TAsphyreDevice do
begin
SpriteEngine := TSpriteEngine.Create(nil);
SpriteEngine.Device:=Sender as TAsphyreDevice;
SpriteEngine.Image := Images;
SpriteEngine.Canvas := Canvas;
Spriteengine.DoMouseEvent := True;
for i := 0 to 20 do
begin
with TSheep.Create(SpriteEngine) do
begin
SetAnim('Walk',0,3,0.1,True);
DoAnimate:=True;
DrawFx:= fxfDiffuse or fxublend;
Width:=40;
Height:=40;
X := Random(750);
Y := Random(550);
FMoveSpeed:=0.5;
FMoveDirection:=TMoveDirection(Random(2));
Tag:= i;
end;
end;
Images.ResolveImage('walk');
SysFonts.CreateFont('s/tahoma', 'tahoma', 12, False, fwtNormal);
end;
end;
2
现在实现TimerEvent过程
procedure TMainForm.TimerEvent(Sender: TObject);
begin
Devices[0].Render(0, DevRender, Self, cRGB1(255,255,0));
Timer.Process();
end;
其中有一个DevRender过程需要完成。这个过程中调用精灵引擎处理精灵。
procedure TMainForm.DevRender(Sender: TAsphyreDevice; Tag: TObject);
begin
DrawEx(Sender.Canvas,Sender.Images.Image['Background'], 0, 0, 0, clWhite4, fxuBlend);
SpriteEngine.Draw;
SpriteEngine.Move(1);
Sender.SysFonts.Font['s/tahoma'].TextOut('"Mouse Click" to make The sheet scare', 200, 480,cRGB1(250,200,0));
Sender.SysFonts.Font['s/tahoma'].TextOut('"Mouse Double Click" to make the sheet run', 200, 500,cRGB1(250,200,0));
Sender.SysFonts.Font['s/tahoma'].TextOut('"Mouse Drag" to move the sheet', 200, 520,cRGB1(250,200,0));
Sender.SysFonts.Font['s/tahoma'].TextOut('"Mouse Wheel" to make the sheet rolling', 200, 540,cRGB1(250,200,0));
Sender.SysFonts.Font['s/tahoma'].TextOut('"Mouse Right Click" to make the sheet handstand', 200, 560,cRGB1(250,200,0));
Sender.SysFonts.Font['s/tahoma'].TextOut('FPS:'+inttostr(timer.FrameRate), 10, 10,cRGB1(250,200,0));
end;
OK。我们借助Asphyre4.0及Sprite Engine提供的框架已经完成了一个基本的2D游戏。大概过程为初始化设备，初始化显示设备，生成精灵引擎，生成精灵，初始化Timer并指定其TimerEvent。在Timer中调用Render过程绘制背景及精灵动画。
定义精灵
有了上面的代码后，我们就可以向这个框架中添加自己的精灵了。我们在游戏中看到的一切都可以定义为精灵：人物，地图，怪物，喷泉，各种绚丽的特效等等。
可以从TAnimatedSprite，TJumperSprite，TPlaySprite等类中继承自己的精灵。
TMoveDirection=(mdLeft,mdRight); //运动方向
TSheep=class(TAnimatedSprite) //自定义的精灵
private
FMoveSpeed: Single;
FMoveDirection: TMoveDirection;
public
procedure DoMove(const MoveCount: Single); override;
//procedure OnMouseClick(MX,MY:Integer); override;
//procedure OnMouseDbClick; override;
//procedure OnMouseLeave; override;
//procedure OnMouseEnter; override;
//procedure OnMouseDrag(MX,MY:Integer); override;
//procedure OnMouseRClick; override;
//procedure OnMouseWheel; override;
//procedure OnAnimEnd; override;
//property MoveSpeed: Single read FMoveSpeed write FMoveSpeed;
property MoveDirection: TMoveDirection read FMoveDirection write FMoveDirection;
end;
这里我们只实现一个函数 DoMove
procedure TSheep.DoMove(const movecount: Single);
begin
inherited;
ActiveRect:=Rect(Round(X), Round(Y), Round(X+40), Round(Y+40));
case FMoveDirection of
mdLeft:
begin
X:=X- FMoveSpeed;
MirrorX:= True;
end;
mdRight:
begin
X:=X+ FMoveSpeed;
MirrorX:= False;
end;
end;
if (X>750) then FMovedirection:= mdLeft;
if (X<10) then FMovedirection:= mdRight;
DoMouseDrag;
end;
在这个函数中首先获取ActiveRect,这个矩形是精灵的自身所在区域,用于碰撞检测.接下来根据运动方向修改其X坐标.如果到了边界则变向.逻辑很简单.
但是这里我们回头看看初始化精灵的部分有几行很关键的代码:
for i := 0 to 20 do
begin
with TSheep.Create(SpriteEngine) do
begin
SetAnim('Walk',0,2,0.1,True);
DoAnimate:=True;
DrawFx:= fxfDiffuse or fxublend;
Width:=40;
Height:=40;
X := Random(750);
Y := Random(550);
FMoveSpeed:=0.5;
FMoveDirection:=TMoveDirection(Random(2));
Tag:= i;
end;
end;
这里创建了20只羊.粗体部分是设置其动画.动画名称为 Walk 从0开始 共3个图片,动画速度为0.1,循环播放.这时你可能有点晕了 Walk字符串是什么意思?下面我们看看Asphyer对资源的组织.
准备资源
这里分析一下如何组织Asphyre4.0所需的资源.与3.0不同,4.0直接使用XML文件来组织素材图片.我觉得还是很明了的.首先将所需的图片放在一个目录中,图片格式可以是bmp也可以是png格式.可以将动画的每一帧图片存放在一个文件中,也可将一组连续的动画图片放在一个文件中.我们在XML文件中加以指定即可,Asphyer将自动去解析.
下面看相关的XML文件:
1 media.XML
<unires>
<resource source="/images.xml" />
<resource source="/fonts.xml" />
</unires>
这个文件我们不陌生吧,在FormCreate中有两行代码:
ImageGroups.ParseLink('/media.xml'); //图片管理器从media.xml文件中解析图片
FontGroups.ParseLink('/media.xml'); //字体管理器从media.xml文件中解析字体
那么我们可以猜测到,图片管理器肯定是从images.xml中找图片信息了,而字体管理器从fonts.xml中解析字体信息.
好了,下面我们看看images.xml文件的内容.
2 images.xml
为了便于说明,我只将这个xml文件中的部分节写出来.大家看看动画播放的玄机在哪里?
<unires>
<image-group name="/images/base" option="normal">
<image uid="Walk" type="image">
<format type="A4R4G4B4" miplevels="auto"/>
<pattern width="40" height="40" count="2" padx="0" pady="0"/>
<colorkey value="#0000FF"/>
<textures count="1">
<texture num="0" source="/Gfx/walk.bmp"/>
</textures>
</image>
</image-group>
</unires>
上面这段xml代码将gfx/walk.bmp(
<texture num="0" source=
"/Gfx/walk.bmp"/>)文件一份为二(
<pattern width=
"40" height=
"40" count=
"2" padx="0" pady="0"/>),每部分长宽各40,当然walk.bmp的尺寸为80X40.
好了,现在回想一下精灵初始化时的代码
SetAnim('Walk',0,2,0.1,True);在打开Walk.bmp图片看看,是不是豁然开朗了,其中两幅图分别是羊儿站立和走路的姿势,两幅图交替组成动画,一副羊儿行走的动画就产生了.
3
Fonts.xml
这个文件中组织了一下可能用到的字体及其设置.
<unires>
<font-group name="/fonts/all" option="normal">
<font uid="s/tahoma" type="system" name="tahoma" size="12" weight="bold" charset="ansi" quality="cleartype"/>
</font-group>
</unires>
而在初始化的部分可以看到:
SysFonts.CreateFont('s/tahoma', 'tahoma', 12, False, fwtNormal);
已经使用字体输出文字:
Sender.SysFonts.Font['s/tahoma'].TextOut('"Mouse Click" to make The sheet scare', 200, 480,cRGB1(250,200,0));
好了,就写到这里.本文可以让从来没有接触过Asphyre的人对Asphyre有个大体的认识.Asphyre有很多范例,但是开发文档很少.我刚一开始看的时候一头雾水,最后自己分析了一下,按部就班的也写出来了一点小东西了.希望有牛人继续.大家有什么问题可以到火人的bbs上发问:www.huosoft.com.火人老大真的好牛.我的偶像.
有什么错误之处敬请指正.谢谢大家.
最后祝大家学习快乐.